Custom <> text object

angle_bracket_textobj.vim

" Place mappings in:
" ~/.vim/ftplugin/javascriptreact.vim: For JSX
" ~/.vim/ftplugin/typescriptreact.vim: For TSX

onoremap <buffer> a< :<c-u>call <SID>TagTextObject('a')<cr>
xnoremap <buffer> a< :<c-u>call <SID>TagTextObject('a')<cr>
onoremap <buffer> i< :<c-u>call <SID>TagTextObject('i')<cr>
xnoremap <buffer> i< :<c-u>call <SID>TagTextObject('i')<cr>

onoremap <buffer> a> :<c-u>call <SID>TagTextObject('a')<cr>
xnoremap <buffer> a> :<c-u>call <SID>TagTextObject('a')<cr>
onoremap <buffer> i> :<c-u>call <SID>TagTextObject('i')<cr>
xnoremap <buffer> i> :<c-u>call <SID>TagTextObject('i')<cr>

function! s:TagTextObject(mode) abort
  if a:mode == 'a'
    let start_pattern = '<'
    let end_pattern = '[^=]\zs>'
  else " a:mode == 'i'
    let start_pattern = '<\zs\S'
    let end_pattern = '[^=]>'
  endif

  " Find the start of the <tag>:
  if searchpair(start_pattern, '', end_pattern, 'Wbc') <= 0
    return
  endif

  " Save start position in "t" mark:
  normal! mt
  
  " Find the end of the <tag>:
  call searchpair(start_pattern, '', end_pattern, 'W')
  
  " Visual-select from here to the start of the tag:
  normal! v`t
endfunction