Xune PKGBUILD

PKGBUILD

# Maintainer: Cory Sanin <corysanin@outlook.com>

_basename="xune"
pkgname=${_basename}-appimage
pkgdesc="Early test build of Xune, a recreation of the Zune desktop software"
pkgver=0.3.1
_version=v${pkgver}
pkgrel=0
provides=("${_basename}")
conflicts=("${_basename}")
url="https://github.com/magicisinthehole/xune-releases"
arch=(
    x86_64
    aarch64
)
license=("Unknown")
_appimage="${_basename}-${_version}.AppImage"
_amdimage="${_basename}-${_version}-x64.AppImage"
_armimage="${_basename}-${_version}-arm64.AppImage"
source_x86_64=("${_amdimage}"::"https://github.com/xune-software/xune-releases/releases/download/${_version}/Xune-${pkgver}-Linux-x64.AppImage")
source_aarch64=("${_armimage}"::"https://github.com/xune-software/xune-releases/releases/download/${_version}/Xune-${pkgver}-Linux-arm64.AppImage")
sha256sums_x86_64=('696427d3fc6f06e24cf9ef70d848004eacc8b29226d9a6d9fb5a269271dba6bf')
sha256sums_aarch64=('caa85c30faa69edc679e20b89c609535ce7188fe7dbec491b7255287f6d3b135')
options=(!strip)

prepare() {
    # extract for desktop file and icons
    case $CARCH in
        x86_64)
        export _ARCHAPPIMAGE="${_amdimage}"
        ;;
        aarch64)
        export _ARCHAPPIMAGE="${_armimage}"
        ;;
        *)
        exit 1
        ;;
    esac

    chmod +x "${srcdir}/${_ARCHAPPIMAGE}"
    "./${_ARCHAPPIMAGE}" --appimage-extract

    # update exec
    sed -i -E "s:Exec=.*$:Exec=xune:" "${srcdir}/squashfs-root/${_basename}.desktop"
}

package() {
	# Appimage and symlink
    install -Dpm755 "${_ARCHAPPIMAGE}" "${pkgdir}/opt/${pkgname}/${_appimage}"
    install -dm755 "${pkgdir}/usr/bin"
    ln -s "/opt/${pkgname}/${_appimage}" "${pkgdir}/usr/bin/${_basename}"

    # Desktop file
    install -Dm644 "${srcdir}/squashfs-root/${_basename}.desktop" "${pkgdir}/usr/share/applications/${_basename}.desktop"

    # Icons
    install -dm755 "${pkgdir}/usr/share/"
    cp -r --no-preserve=mode,ownership "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
}