RunAOMWithHamachi.bat

@echo off

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"
exit /B

:gotAdmin
pushd "%~dp0"

setlocal EnableExtensions EnableDelayedExpansion

set "HAMACHI_BAT=C:\Users\User\Iniciar Hamachi.bat"
set "SERVICO=Hamachi2Svc"
set "SERVICO2=LMIGuardianSvc"
set "PROCESSO_HAMACHI=hamachi-2-ui.exe"

set "JOGO_EXE=C:\Games\Age of Mythology\AomNetworkPatch.exe"
set "JOGO_ARGS=+noIntroCinematics xres=1920 yres=1080"

set "MAX_TENTATIVAS=30"
set "ESPERA_SEGUNDOS=2"

if not exist "%HAMACHI_BAT%" (
    echo ERRO: Nao encontrei o arquivo:
    echo "%HAMACHI_BAT%"
    pause
    exit /b 1
)

if not exist "%JOGO_EXE%" (
    echo ERRO: Nao encontrei o executavel do jogo:
    echo "%JOGO_EXE%"
    pause
    exit /b 1
)

call "%HAMACHI_BAT%"
echo Iniciando Hamachi...

echo.
echo Aguardando o Hamachi ficar pronto...

for /L %%I in (1,1,%MAX_TENTATIVAS%) do (
    set "SERVICO_OK=0"
    set "SERVICO2_OK=0"
    set "PROCESSO_OK=0"

    sc.exe query "%SERVICO%" | find /I "RUNNING" >nul 2>&1
    if not errorlevel 1 set "SERVICO_OK=1"

    sc.exe query "%SERVICO2%" | find /I "RUNNING" >nul 2>&1
    if not errorlevel 1 set "SERVICO2_OK=1"

    tasklist /FI "IMAGENAME eq %PROCESSO_HAMACHI%" /NH | find /I "%PROCESSO_HAMACHI%" >nul 2>&1
    if not errorlevel 1 set "PROCESSO_OK=1"

    if "!SERVICO_OK!"=="1" if "!PROCESSO_OK!"=="1" goto HAMACHI_OK

    echo Tentativa %%I/%MAX_TENTATIVAS%: aguardando %ESPERA_SEGUNDOS% segundos...
    timeout /t %ESPERA_SEGUNDOS% /nobreak >nul
)

echo.
echo ERRO: O Hamachi nao ficou pronto dentro do tempo limite.
echo.

echo Status do servico %SERVICO%:
sc.exe query "%SERVICO%"

echo Status do servico %SERVICO2%:
sc.exe query "%SERVICO2%"

echo.
echo Verificacao do processo %PROCESSO_HAMACHI%:
tasklist /FI "IMAGENAME eq %PROCESSO_HAMACHI%"

echo.
echo O jogo nao sera iniciado.
pause
exit /b 1

:HAMACHI_OK
echo.
echo Hamachi OK.
echo Iniciando Age of Mythology...
cd "C:\Games\Age of Mythology\"
start "" /D "C:\Games\Age of Mythology" "%JOGO_EXE%" %JOGO_ARGS%

exit /b 0