Write HTML documents with Jsonnet using JsonML

JsonML.jsonnet

local element = {
  new(tagName, attributes={}): {
    tagName: tagName,
    attributes: attributes,
    elementList: [],

    render()::
      [
        self.tagName,
        self.attributes,
        '\n',
      ]
      + [
        if std.mod(i, 2) == 0
        then
          local el = self.elementList[(i / 2)];
          if std.isObject(el) && 'render' in el
          then self.elementList[(i / 2)].render()
          else el
        else '\n'
        for i in std.range(0, (std.length(self.elementList) * 2) - 1)
      ],

    manifest()::
      std.manifestXmlJsonml(
        self.render()
      ),
  },

  addElements(el): {
    elementList+:
      if std.isArray(el)
      then el
      else [el],
  },
};
local title =
  element.new('title')
  + element.addElements('This is a title');

local pageTitle =
  element.new('h1')
  + element.addElements('This is a page title');

local doc =
  element.new('html')
  + element.addElements([
    element.new('head')
    + element.addElements([title]),
    element.new('body')
    + element.addElements([pageTitle]),
  ]);

doc.manifest()