janus-gateway-git

PKGBUILD

# Maintainer: Maurizio Porrato <[email protected]>

pkgname=janus-gateway-git
pkgver=0.0.9.r239.ga6c2572
pkgrel=1
pkgdesc="WebRTC gateway."
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="http://janus.conf.meetecho.com/"
license=('GPL3')
depends=('libmicrohttpd' 'jansson' 'libnice' 'openssl' 'libsrtp' 'sofia-sip' 'libusrsctp-git' 'libwebsockets-git' 'libevent' 'librabbitmq-c' 'opus' 'libogg' 'glib2' 'ding-libs')
makedepends=('git' 'libtool' 'automake' 'autoconf' 'gcc' 'make' 'pkg-config' 'gengetopt' 'patch')
provides=(janus-gateway)
backup=('etc/janus/janus.cfg')
install=janus-gateway-git.install

source=(
  'git+https://github.com/meetecho/janus-gateway.git'
  'https://github.com/meetecho/janus-gateway/pull/438.patch'
)
md5sums=(
  'SKIP'
  'SKIP'
)
_gitname="janus-gateway"

prepare() {
  cd "$srcdir/${_gitname}"
  patch -Np1 -i ../438.patch
}

pkgver() {
  cd "$srcdir/${_gitname}"
  git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g;s/^v//'
}

build() {
  cd "$srcdir/${_gitname}"
  ./autogen.sh
  ./configure --prefix=/usr --sysconfdir=/etc --disable-docs
  DESTDIR="$pkgdir/" make
}

package() {
  cd "$srcdir/${_gitname}"
  DESTDIR="$pkgdir/" make install configs
  rm -f "$pkgdir/usr/share/janus/certs/mycert.{key,pem}"
}