ZX Spectrum 2px scroll example

rl-sp-2px.asm

	DEVICE ZXSPECTRUM48

	ORG #8000

TEST
	ld hl,0
	ld de,#4000
	ld bc,#1800
	ldir

RL2X
	di
	ld (.savesp),sp
	ld a,#13
	exa
	ld a,128
.loop3
	exa
.loop2
	ld lx,a
	sub 12
	ld ly,a
	sub 6
	ld (.screen_06),a
	ld a,#40
	ld hx,a
	ld hy,a
.loop
	ld (.screen_06+1),a
	ld sp,ix
	pop bc
	pop de
	pop hl
	exx
	pop bc
	pop de
	pop hl
	sla h
	rl l
	rl d
	rl e
	rl b
	rl c
	rla		;C<-0 %0000 0001
	sla h
	rl l
	rl d
	rl e
	rl b
	rl c
	rra		;%2000 0000 1->C
	push hl
	push de
	push bc
	exx
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	rla		;C<-2 %0000 0001
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	rra		;%2000 0000 1->C
	push hl
	push de
	push bc
	ld sp,iy
	pop bc
	pop de
	pop hl
	exx
	pop bc
	pop de
	pop hl
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	rla
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	rra
	push hl
	push de
	push bc
	exx
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	rla
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	rra
	push hl
	push de
	push bc
.screen_06=$+1
	ld sp,#4001
	pop bc
	pop de
	pop hl
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	rla
	rl h
	rl l
	rl d
	rl e
	rl b
	rl c
	push hl
	push de
	push bc
	inc hx
	inc hy
	ld a,hx
	cp #58
	jp c,.loop
	ld a,lx
	add #20
	jp nc,.loop2
	exa
	dec a
	jp nz,.loop3
.savesp=$+1
	ld sp,0
	ld iy,#5C3A
	ld hl,#2758
	exx
	ei
	ret

	SAVESNA "rl-sp-2px.sna",TEST