Example of [justfile](https://just.systems/man/en/)

justfile

scheme := "CalSync"
config := "Release"
install_dir := env("HOME") / "Applications"
app_name := "CalSync.app"

# Default: build and install
default: install

# Build the app (ad-hoc signed for local use)
build:
    xcodebuild -scheme {{scheme}} -configuration {{config}} build

# Clean build
clean-build:
    xcodebuild -scheme {{scheme}} -configuration {{config}} clean build

# Run tests
test:
    xcodebuild -scheme {{scheme}} -configuration Debug test

# Kill running app, build, and install to ~/Applications
install: build
    -pkill -x CalSync
    sleep 1
    mkdir -p {{install_dir}}
    rm -rf {{install_dir}}/{{app_name}}
    cp -R $(xcodebuild -scheme {{scheme}} -configuration {{config}} \
        -showBuildSettings 2>/dev/null | grep -m1 'BUILT_PRODUCTS_DIR' | \
        awk '{print $3}')/{{app_name}} {{install_dir}}/
    @echo "Installed to {{install_dir}}/{{app_name}}"

# Install and launch
run: install
    open {{install_dir}}/{{app_name}}

# Regenerate Xcode project from project.yml
generate:
    xcodegen generate

# Clean derived data
clean:
    xcodebuild -scheme {{scheme}} clean