build.gradle.kts

plugins {
    id("java")
    id("com.gradleup.shadow") version "8.3.2"
    id("io.github.revxrsal.zapper") version "1.0.3"
}

repositories {
    maven(url = "https://libraries.minecraft.net/")
    maven(url = "https://repo.dmulloy2.net/repository/public/")
    mavenLocal()
}

dependencies {
    compileOnly("org.spigotmc:spigot-api:1.14.4-R0.1-SNAPSHOT")
    compileOnly("com.mojang:authlib:1.5.25")
    compileOnly("io.netty:netty-all:4.0.23.Final")
    compileOnly("com.sk89q.worldedit:worldedit-bukkit:6.1.9")
    compileOnly("com.comphenix.protocol:ProtocolLib:5.1.0")

    zap("com.zaxxer:HikariCP:4.0.3")
    zap("org.bstats:bstats-bukkit:3.0.2")
    zap("net.kyori:adventure-api:4.20.0")
    zap("net.kyori:adventure-platform-bukkit:4.3.4")
    zap("net.kyori:adventure-text-minimessage:4.20.0")
    zap("net.kyori:adventure-text-serializer-plain:4.20.0")
    zap("net.kyori:adventure-text-serializer-legacy:4.20.0")
    zap("net.kyori:adventure-text-serializer-gson:4.20.0") { exclude(module = "gson") }
    zap("fr.mrmicky:fastboard:2.1.4")
    zap("io.github.revxrsal:lamp.common:4.0.0-rc.12")
    zap("io.github.revxrsal:lamp.brigadier:4.0.0-rc.12")
    zap("io.github.revxrsal:lamp.bukkit:4.0.0-rc.12")
    zap("org.ow2.asm:asm:9.8")
    zap("org.ow2.asm:asm-commons:9.8")
    zap("com.squareup.moshi:moshi:1.15.2")
    zap("com.squareup.moshi:moshi-adapters:1.15.2")
    zap("com.github.cryptomorin:XSeries:13.3.0")
    zap("com.github.ben-manes.caffeine:caffeine:2.9.3")
}

zapper {
    libsFolder = "libs"
    relocationPrefix = "revxrsal.xxx.libs"

    repositories { includeProjectRepositories() }

    relocate("org.objectweb.asm", "asm")
    relocate("revxrsal.commnds", "lamp")
    relocate("com.squareup.moshi", "moshi")
    relocate("org.bstats", "bstats")
    relocate("com.cryptomorin.xseries", "xseries")
    relocate("fr.mrmicky.fastboard", "fastboard")
    relocate("com.zaxxer.hikari", "hikari")

    relocate("org.mariadb.jdbc", "mariadb")
    relocate("com.mysql", "mysql")
    relocate("org.postgresql", "postgresql")
}

tasks.withType<JavaCompile> {
    options.compilerArgs.add("-parameters")
}

tasks.withType<ProcessResources> {
    filesMatching("plugin.yml") {
        expand("version" to project.version)
    }
}

val shadowJar = tasks.named("shadowJar")

configurations {
    create("shaded")
}

artifacts {
    add("shaded", shadowJar)
}