PlatformColorMode.pas

unit PlatformColorMode;

interface

uses
  FMX.Platform
  {$IFDEF MSWINDOWS}
  , System.SysUtils, System.Win.Registry, Winapi.Windows
  {$ENDIF}
  ;

function GetSystemTheme: TSystemThemeKind;

implementation

function GetSystemTheme: TSystemThemeKind;
  {$IFDEF MSWINDOWS}
const
  RegThemeKey = 'Software\Microsoft\Windows\CurrentVersion\Themes\Personalize\';
  RegThemeVal = 'AppsUseLightTheme';
  {$ENDIF}
var
  {$IFDEF MSWINDOWS}
  Reg: TRegistry;
  {$ELSE}
  LService: IFMXSystemAppearanceService;
  {$ENDIF}
begin

  Result := TSystemThemeKind.Unspecified;

  {$IFDEF MSWINDOWS}

  Reg := TRegistry.Create;
  try
    Reg.RootKey := HKEY_CURRENT_USER;

    if Reg.KeyExists(RegThemeKey) then
      if Reg.OpenKey(RegThemeKey, False) then
      try
        if Reg.ValueExists(RegThemeVal) then
           if Reg.ReadInteger(RegThemeVal) = 0 then
            Result := TSystemThemeKind.Dark
           else
            Result := TSystemThemeKind.Light;
      finally
        Reg.CloseKey;
      end;

  finally
    Reg.Free;
  end;
  {$ELSE}
  if TPlatformServices.Current.SupportsPlatformService(IFMXSystemAppearanceService, LService) then
    Result := LService.GetSystemThemeKind;
  {$ENDIF}

end;

end.