back.cmd - Backup di file e cartella da un file -ini - cmd.exe semplice senza TCC/LE

back.cmd

@Echo off
SETLOCAL ENABLEDELAYEDEXPANSION
CD /D "%~d0%~p0"
IF "%1" == "" GOTO nopar
IF NOT EXIST "%1" GOTO nodest

SET /P _scelta=Cartella di destinazione "%1\", e' corretto? (S/N)? || SET _scelta=N
IF "%_scelta%" NEQ "s" EXIT /B

SET DEST=%1
SET EXEC=Robocopy 
SET OPT=/mir /xj /e /R:2 /W:5 /XO
::SET OPT=/mir /xj /e /R:2 /W:5 /LOG:BackLogfile.txt /NFL /NDL
:: file di configurazione delle cartelle e file da backupare su back.ini
:: i commenti cominciano con #
:: per il backup si usa robocopy
CLS
for /f "eol=# tokens=1-2 delims=," %%A in (back.ini) do IF "%%A" EQU "F" call:COPIAFILE %%A %%B

for /f "eol=# tokens=1-2 delims=," %%A in (back.ini) do IF "%%A" EQU "D" call:COPIADIR %%A %%B

Exit /b
:COPIADIR
SET DESTFOLDER=%~nx2
echo Inizio copia di %1 %2
::ECHO %DESTFOLDER%
wait 3 
:: ESEGUE COMANDO BACKUP
%EXEC% %2 "%DEST%\%DESTFOLDER%" %OPT%
GOTO:EOF
EXIT /B
:COPIAFILE
echo Inizio copia di %1 %2
wait 3
COPY /Y %2 "%DEST%" 
GOTO:EOF
EXIT /B
:nopar
Echo Manca la cartella di destinazione
Echo.
Echo ESEMPIO: back.cmd d:\backup
exit /b
:nodest
Echo La destinazione non esiste "%1"
exit /b

back.ini

#Cartelle da backupare
D,"C:\script"
D,"C:\Users\Andrea\Copy"
D,"C:\Users\Andrea\Desktop\FilmFE"
D,"C:\ProgramData\WoodWing"
D,"C:\Users\Andrea\Desktop\FilmFE"
F,"C:\Windows\System32\drivers\etc\hosts"
D,"C:\Users\Andrea\ConEmu"
D,"C:\Users\Andrea\Apps"
D,"C:\Program Files (x86)\Cisco Systems\VPN Client\Profiles"
D,"C:\Users\Andrea\Downloads\Symbian"