Script for configuring IIS for my microservices

configureiis.bat

@echo off
SETLOCAL
SET project=%1
SET service=%2
SET dir=%3
IF [%1] == [] GOTO ERROR_USAGE
IF [%2] == [] GOTO ERROR_USAGE
IF [%3] == [] GOTO ERROR_USAGE

SET cmd=C:\Windows\System32\inetsrv\appcmd.exe
SET dns=%project%-%service%
SET publishDir=%dir%\%project%\%service%
SET environmentVariablesScript=.\%project%.%service%\%project%.%service%\Properties\addEnvironmentVariables.bat

ECHO Configure IIS Script
ECHO Project : %project%
ECHO Service : %service%
ECHO Pub dir : %publishDir%
ECHO DNS     : %dns%

ECHO Creating project dir
if not exist %publishDir% mkdir %publishDir%

ECHO Creating AppPool
%cmd% add apppool /name:%dns% /managedRuntimeVersion:""

ECHO Creating %service% site
%cmd% add site /name:%dns% /bindings:http://%dns%.local.com:80 /physicalpath:%publishDir%

ECHO Add %service% to apppool
%cmd% set app "%dns%/" /applicationpool:%dns%

ECHO Add Environment Variables
IF EXIST %environmentVariablesScript% CALL %environmentVariablesScript% %dns%

ECHO Adding host entry
ECHO 127.0.0.1   %dns%.local.com >> c:\windows\system32\drivers\etc\hosts
GOTO EOF
ENDLOCAL

:ERROR_USAGE
ECHO Usage: configureiis.bat [project] [service name] [pub directory]
GOTO EOF

:EOF
ECHO END