base model

moduleKeywords = ['extended', 'included']

class NvModel

  @_resource = {}
  @_all = []

  @all: ->

    models = _.map @_all, (model) =>
      model = new @(model)

    $q.when models

  @getEntityDefinition: () ->
    @_resource.getEntityDefinition()

  ###*
   * Extend the Class object
   * @param  {Object} obj Give an object of methods
   * @return {Object}     Return the current model
  ###
  @extend: (obj) ->
    for key, value of obj when key not in moduleKeywords
      @[key] = value

    obj.extended?.apply(@)
    this

  ###*
   * Extend the Instance object
   * @param  {Object} obj Give an object of methods
   * @return {Object}     Return the current model
  ###
  @include: (obj) ->
    for key, value of obj when key not in moduleKeywords
      # Assign properties to the prototype
      @::[key] = value

    obj.included?.apply(@)
    this

  constructor: (entity) ->
    angular.extend @, entity
    @_resource.getEntityDefinition()
    _.defaults @, @_resource.properties

  sendToServer: ->
    @_resource.entity = _.omit @, '_resource'
    @_resource.create()