square zoom

squareZoom.pde

// zooming squares. by dave

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 480;       
float shutterAngle = .4;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  pixelDensity(recording ? 1 : 2);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  ortho();
  colorMode(HSB, 1);
  strokeWeight(2.5);
}

float x, y, z, tt;
int N = 10;
float l = 100, ll, L = 38;

void grid(int level, float q) {
  fill(0);
  ll = l*pow(.5, .5*level);
  push();
  translate(0, 0, level);
  if (level%2 != 0)
    rotate(QUARTER_PI);
  for (int i=-N; i<N; i++) {
    for (int j=-N; j<N; j++) {
      x = i*ll;
      y = j*ll;
      tt = c01(4*q - 3*map(atan2(width/2-screenX(x, y), screenY(x, y)-height/2), -PI, PI, 0, 1));
      tt = ease(tt);
      push();
      translate(x, y);
      if ((i+j)%2 != 0)
        rect(0, 0, ll*tt, ll*tt);
      pop();
    }
  }
  pop();
}

void draw_() {
  background(0); 
  push();
  translate(width/2, height/2);
  if (t <= .5) {
    t = 2*t;
    l = L*pow(4, t);
    for (int i=-4; i<4; i++) {
      stroke((i*.125+10+.04)%1, 1, 1);
      grid(i, c01(t-.25*i));
    }
  } else {
    t = 2*t-1;
    l = L*pow(4, t);
    for (int i=-4; i<4; i++) {
      stroke((i*.125+10+.54)%1, 1, 1);
      grid(i, c01(t-.25*i));
    }
  }
  pop();
}