circle square dance

circleSquareDance.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 140;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  smooth(8);  
  rectMode(CENTER);
  pixelDensity(recording ? 1 : 2);
  result = new int[width*height][3];
  stroke(250, 50, 200);
  strokeWeight(3);
  ortho();
  noFill();
}

float x, y, z, tt;
int N = 240;
float R = 75, r, th;

void thing(float q) {
  beginShape();
  for (int i=0; i<N; i++) {
    th = TWO_PI*i/N;
    r = lerp(R*cos(QUARTER_PI)/cos(((th+QUARTER_PI)%HALF_PI)-QUARTER_PI), R*lerp(sqrt(.5), 1, .5), q);
    vertex(r*cos(th), r*sin(th));
  }
  endShape(CLOSE);
}

float ee = 3;

void things() {
  if (t <= .5) {
    for (int i=-4; i<5; i++) {
      for (int j=-4; j<5; j++) {
        push();
        translate(sqrt(2)*i*R, sqrt(2)*j*R);
        if ((i+j)%2 == 0)
          thing(ease(map(cos(TWO_PI*2*t),1,-1,0,1),ee));
        pop();
      }
    }
  }
  else {
    for (int i=-4; i<5; i++) {
      for (int j=-4; j<5; j++) {
        push();
        translate(sqrt(2)*i*R, sqrt(2)*j*R);
        if ((i+j)%2 != 0)
          thing(ease(map(cos(TWO_PI*2*t),1,-1,0,1),ee));
        pop();
      }
    }
  }
}

void draw_() {
  background(15);
  push();
  translate(width/2, height/2);
  stroke(250);
  strokeWeight(10);
  things();
  
  stroke(15);
  strokeWeight(5);
  push();
  translate(0,0,1);
  things();
  pop();
  pop();
}