labmbda interpretation.hs

{-# LANGUAGE BlockArguments #-}
{-# LANGUAGE LambdaCase     #-}

import Control.Monad.State

data Action
  = For Expr (Expr -> Action)
  | Print Expr

data Expr
  = Var String
  | Range Int
  | Literal Integer
  | Mult Expr Expr

instance Num Expr where
  (*) = Mult
  fromInteger = Literal

interpret :: Action -> String
interpret action = evalState (interpretAction action) 0

interpretAction :: Action -> State Int String
interpretAction = \case
  For seq body -> do
    var <- freshVar
    body' <- interpretAction (body $ Var var)
    pure $ unwords ["for", var, "in", interpretExpr seq, "{", body', "}"]
  Print expr -> pure $ "print(" <> interpretExpr expr <> ")"

freshVar :: State Int String
freshVar = state \i -> ("var" ++ show i, i + 1)

interpretExpr :: Expr -> String
interpretExpr = \case
  Var v -> v
  Range i -> "range(" ++ show i ++ ")"
  Literal i -> show i
  Mult a b -> "(" ++ interpretExpr a ++ " * " ++ interpretExpr b ++ ")"

program = For (Range 10) \i -> Print (2 * i)

-- $> print $ interpret program
-- "for var0 in range(10) { print((2 * var0)) }"