ANTLR4 grammar for parsing Newick trees

Newick.g4

// A Newick grammar based on the specification by Gary Olsen: available at
// https://phylipweb.github.io/phylip/newick_doc.html The grammar does _not_ include the optional
// comments as I have not figured out how to include them without adding a lot of `comment?` rules
// to the grammar whick makes it very slow.

grammar Newick;

tree: descendantList rootLabel? branchLength? SEMI;
descendantList: LPAREN subtree (COMMA subtree)* RPAREN;
subtree: (descendantList internalNodeLabel? | leafLabel) branchLength?;
rootLabel: label;
internalNodeLabel: label;
leafLabel: label;
label: (unquotedLabel | quotedLabel);
unquotedLabel: STRING;
quotedLabel:
	SQUOTE (
		STRING
		| LPAREN
		| RPAREN
		| COMMA
		| SEMI
		| WS
		| COLON
		| doubleSquote
	)* SQUOTE;
doubleSquote: SQUOTE SQUOTE;
branchLength: COLON (SIGNED_NUMBER | UNSIGNED_NUMBER);

// Lexer Rules
LPAREN: '(';
RPAREN: ')';
COMMA: ',';
SEMI: ';';
COLON: ':';
SQUOTE: '\'';
SIGNED_NUMBER: '-'? UNSIGNED_NUMBER;
UNSIGNED_NUMBER: [0-9]+ ('.' [0-9]+)?;
STRING: ~[ \t\r\n()[\],;:']+;
WS: [ \t\r\n]+ -> skip;