A class-based template for jQuery plugins in Coffeescript

jquery-plugin-template.coffee

# $('.target').myPlugin(); 
# $('.target').myPlugin({ paramA: 'not-foo' });
# $('.target').myPlugin('myMethod', 'Hello, world');

do($ = window.jQuery, window) ->

  # Define the plugin class
  class MyPlugin

    defaults:
      paramA: 'foo'
      paramB: 'bar'

    # Construct / init the plugin
    constructor: (el, options) ->
      @options = $.extend({}, @defaults, options)
      @$el = $(el)
      @bind()

    # Bind event handlers
    bind: ->
      @$el.on 'click', ->
        console.log 'Clicked'

    # Additional plugin methods go here
    myMethod: (echo) ->
      @$el.html(@options.paramA + ': ' + echo)

  # Define the plugin
  $.fn.extend myPlugin: (option, args...) ->
    @each ->
      $this = $(this)
      data = $this.data('myPlugin')

      if !data
        $this.data 'myPlugin', (data = new MyPlugin(this, option))
      if typeof option == 'string'
        data[option].apply(data, args)