Mura CMS: Bootstrap Carousel Example Using Local Content Index

muraBootstrapCarousel.cfm

<!--- BEGIN: Bootstrap Carousel --->
<cfset feed=$.getBean('feed').loadBy(name='Your FeedName Goes Here')>
<cfset iterator=feed.getIterator()>
<cfif iterator.hasNext()>
	<div id="myCarousel" class="carousel slide">
		<!--- Carousel items --->
		<div class="carousel-inner">
			<cfset idx = 0>
			<cfloop condition="iterator.hasNext()">
				<cfset item=iterator.next()>
				<cfif listFindNoCase('jpg,jpeg,gif,png', ListLast(item.getImageURL(), '.'))>
					<cfset idx++>
					<div class="item<cfif idx eq 1> active</cfif>">
						<img src="#item.getImageURL(width=1200,height=500)#" alt="#HTMLEditFormat(item.getTitle())#">
						<div class="carousel-caption">
							<h4><a href="#item.getURL()#">#HTMLEditFormat(item.getTitle())#</a></h4>
							#item.getSummary()#
						</div>
					</div>
				</cfif>
			</cfloop>
		</div>
		<cfif idx>
			<!--- Carousel nav --->
			<cfif idx gt 1>
				<a class="left carousel-control" href="##myCarousel" data-slide="prev">&lsaquo;</a>
				<a class="right carousel-control" href="##myCarousel" data-slide="next">&rsaquo;</a>
			</cfif>
		<cfelse>
			<div class="alert alert-info alert-block">
				<button type="button" class="close" data-dismiss="alert">x</button>
				<h4>Oh snap!</h4>
				Your feed has no items <em>with images</em>.
			</div>
		</cfif>
	</div>
<cfelse>
	<div class="alert alert-info alert-block">
		<button type="button" class="close" data-dismiss="alert">x</button>
		<h4>Heads up!</h4>
		Your feed has no items.
	</div>
</cfif>
<!--- // END: Bootstrap Carousel --->