Generic Singleton Pattern in Delphi

Project1.dpr

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  uSingletonGeneric in 'uSingletonGeneric.pas',
  uMyClass in 'uMyClass.pas';

var
  oSingleton1  : TMyClass;
  oSingleton2  : TMyClass;
  oNoSingleton : TMyClass;
begin
  ReportMemoryLeaksOnShutdown := true;

  oNoSingleton := TMyClass.Create;
  oSingleton1  := TMyClassSingleton.GetInstance();
  oSingleton2  := TMyClassSingleton.GetInstance();
  try
    try
      oNoSingleton.Value := 1;
      oSingleton1.Value  := 2;
      oSingleton2.Value  := 3;

      Writeln(Format('NoSingleton: %d | Singleton1: %d | Singleton2: %d',[oNoSingleton.Value,
                                                                          oSingleton1.Value,
                                                                          oSingleton2.Value]));
      Readln;
    except
      on E: Exception do
        Writeln(E.ClassName, ': ', E.Message);
    end;
  finally
    oNoSingleton.free;
  end;
end.

{
###OUTPUT###

  NoSingleton: 1 | Singleton1: 3 | Singleton2: 3
  
}

uMyClass.pas

unit uMyClass;

interface

uses uSingletonGeneric;

type
  TMyClass = class
  strict private
    FValue : integer;
  public
    property Value : Integer read FValue write FValue;
  end;

  TMyClassSingleton = TSingleton<TMyClass>;

implementation

initialization
finalization
  TMyClassSingleton.ReleaseInstance();

end.

uSingletonGeneric.pas

unit uSingletonGeneric;

interface

type
  TSingleton<T: class, constructor> = class
  strict private
    class var FInstance : T;
  public
    class function GetInstance(): T;
    class procedure ReleaseInstance();
  end;

implementation

{ TSingleton<T> }

class function TSingleton<T>.GetInstance: T;
begin
  if not Assigned(Self.FInstance) then
    Self.FInstance := T.Create();
  Result := Self.FInstance;
end;

class procedure TSingleton<T>.ReleaseInstance;
begin
  if Assigned(Self.FInstance) then
    Self.FInstance.Free;
end;

end.

In ReleaseInstance is missing a Self.FInstanec := nil