AoC2024 Day 3

day3.lisp

 (defvar *input*
  (uiop:read-file-string "day3.txt"))

(defun eval-muls (blob)
  (let ((sum 0))
    (ppcre:do-register-groups ((#'parse-integer i) (#'parse-integer j))
        ("mul\\(([0-9]+),([0-9]+)\\)" blob sum)
      (incf sum (* i j)))))

(defun eval-muls* (blob)
  (let ((do-re "do\\(\\)")
        (dont-re "don't\\(\\)"))
    (labels ((aux (blob enabled sum)
               (cond
                 ((null blob) sum)
                 (enabled
                  (multiple-value-bind (mbeg mend) (ppcre:scan dont-re blob)
                    (let ((current (subseq blob 0 mbeg))
                          (rest (when mend (subseq blob mend))))
                      (aux rest (not enabled) (+ sum (eval-muls current))))))
                 (t                     ; not enabled
                  (multiple-value-bind (mbeg mend) (ppcre:scan do-re blob)
                    (declare (ignore mbeg))
                    (aux (when mend (subseq blob mend)) (not enabled) sum))))))
      (aux blob t 0))))