Excel Formulas

excel_formulas_ref.txt

# Toggle absolute reference
F4

# Strikethrough hotkey
Ctrl + 5

# Check if value is in a sheet/column A, return bool

=IF(ISERROR(VLOOKUP(A2,'Sheet1'!A:A, 1, FALSE)),FALSE,TRUE )

# Index-Match value in A, return value in B

=INDEX(Sheet1!B:B, MATCH(A2,Sheet1!A:A,0))

# LCG DAX Template Cube Value, where I points to section number and column filter, A is measure selection, and B is row level filter

=IFERROR(CUBEVALUE("ThisWorkbookDataModel",OFFSET(I$18,$A31,0),I$27,$B31),0)

# Extract CUBEMEMBER object

=MID(FORMULATEXT(A2),FIND("[",FORMULATEXT(A2)),LEN(FORMULATEXT(A2))-FIND("[",FORMULATEXT(A2))-1)

# Update SQL key-pair

=CONCATENATE("('",A2,"','",B2,"'),")

# SQL WHERE IN

=CONCATENATE("'",A2,"',")

# Check if value is in either colomn A or B, etc, in Sheet1

=OR(IFERROR(MATCH(A2, Sheet1!A:A, 0),FALSE), IFERROR(MATCH(A2,Sheet1!B:B,0), FALSE))

# Check if value appears more than once on Sheet1, return bool

=COUNTIF(Sheet1!A:A, A2) > 1

# If key is on Sheet1, use Sheet1 column B value, else use Sheet2 column B value

=IFERROR(INDEX(Sheet1!B:B, MATCH(A2,Sheet1!A:A,0)), INDEX('Sheet2!B:B, MATCH(A2,Sheet2!A:A,0)))

# Slice text prefix off a number

=RIGHT(A2,LEN(A2)-(MIN(FIND({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))) +1)

# Slice text prefix off number only if it's "A" or "B"

=IF(OR(LEFT(A2,MIN(FIND({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))-1)="A", LEFT(A2,MIN(FIND({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))-1)="B"), RIGHT(A2,LEN(A2)-(MIN(FIND({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))) +1), A2)

# Split text at " - " delimiter; original text in column A, first half in column B, second half column C

## Column B
=LEFT(A2,FIND(" - ",A2)-1)
## Column C
=RIGHT(A2,LEN(A2)-FIND(" - ",A2)-1)

# Cut last sentence off

=LEFT(A2,FIND("$",SUBSTITUTE(A2,".","$",(LEN(A2)-LEN(SUBSTITUTE(A2,".","")))-1)))

# Isolate last sentence

=RIGHT(A2,LEN(A2)-FIND("$",SUBSTITUTE(A2,".","$",(LEN(A2)-LEN(SUBSTITUTE(A2,".","")))-1)))

# Reduce paragraph to 140 characters or less in complete sentences

=LEFT(MID(A2,1,140),FIND("$",SUBSTITUTE(MID(A2,1,140),".","$",140-LEN(SUBSTITUTE(MID(A2,1,140),".","")))))

# Retrieve Slicer selection from Data Model slicer (works for single select)

=CUBERANKEDMEMBER("ThisWorkbookDataModel",Slicer_,1)

# Retrieve filename

=MID(CELL("filename"),SEARCH("[",CELL("filename"))+1, SEARCH("]",CELL("filename"))-SEARCH("[",CELL("filename"))-1)

# Count number of rows from the top column text based on text in A5

=MATCH(A5,$A:$A,0)-MATCH($A$1,$A:$A,0)

VBA is for the weak.