pucoti.nix

{pkgs}: let
  pname = "pucoti";
  version = "0.8.3";

  luckypot = let
    pname = "luckypot";
    version = "master";
  in
    python.pkgs.buildPythonPackage {
      inherit pname version;

      src = pkgs.fetchFromGitHub {
        owner = "ddorn";
        repo = "luckypot";
        rev = "9eb18eff31294855a7527c6363c5839a78774dcd";
        hash = "sha256-GPu1lzNO2rbcFPmzsLhtT+ugll9wNlfCQpr+3Y9YIl4=";
      };

      propagatedBuildInputs = with python.pkgs; [pygame-ce];

      doCheck = false;
      pyproject = true;

      build-system = with pkgs.python312Packages; [poetry-core];
    };

  python = pkgs.python312.override {
    packageOverrides = self: super: {
      uvicorn = super.uvicorn.overridePythonAttrs (oldAttrs: rec {
        version = "0.30.5";
        src = pkgs.fetchFromGitHub {
          owner = "encode";
          repo = "uvicorn";
          rev = version;
          sha256 = "sha256-LZcqV9IzL4RoEcEz8oGohzp1+Foq+ZyVnVTxkIltBZ8=";
        };
      });
    };
  };
in
  python.pkgs.buildPythonApplication {
    inherit pname version;
    src = pkgs.fetchFromGitHub {
      owner = "ddorn";
      repo = pname;
      rev = "936cabfd6beb4a8d5507a58719d59b10d35b00cf";
      hash = "sha256-SkEHVYHNRk69YTK7v9x+8GrNU/Y+DEFgKFKc/+3L4xw=";
    };

    doCheck = false;
    pyproject = true;

    propagatedBuildInputs = with python.pkgs; [
      uvicorn
      pyyaml
      pygame-ce
      fastapi
      typer
      requests
      luckypot
    ];

    build-system = with pkgs.python312Packages; [
      poetry-core
    ];
  }