PKGBUILD for mingw-w64-minizip

PKGBUILD

_pkgname=minizip
pkgname=mingw-w64-${_pkgname}
pkgver=2.3.8
pkgrel=1
epoch=1
pkgdesc='ZIP file extraction library (mingw-w64)'
url='https://github.com/nmoinvaz/minizip'
license=('ZLIB' 'custom')
arch=('any')
makedepends=('git' 'mingw-w64-cmake' 'mingw-w64-configure')
options=('!buildflags' 'staticlibs' '!strip')
depends=('mingw-w64-zlib')
source=("https://github.com/nmoinvaz/minizip/archive/${pkgver}.tar.gz")
sha256sums=("8752d8a3d45f264d36e427774118f94d507236482698736c6194ca00cef91df6")

_architectures="i686-w64-mingw32 x86_64-w64-mingw32"


build() {
  cd ${srcdir}/${_pkgname}-${pkgver}
  for _arch in ${_architectures}; do
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-cmake ..
    ${_arch}-cmake --build .
    popd
  done
}

package() {
  for _arch in ${_architectures}; do
    cd "${srcdir}/${_pkgname}-${pkgver}/build-${_arch}"
    make install DESTDIR="$pkgdir"
    ${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
    ${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
  done
}