build.gradle

apply plugin: "com.android.application"
apply plugin: "org.jetbrains.kotlin.android"
apply plugin: 'com.google.gms.google-services'
apply plugin: "com.facebook.react"

project.ext.defaultEnvFile = "env/.dev"
project.ext.envConfigFiles = [
        devdebug  : 'env/.dev',
        devrelease: 'env/.dev',
        stagdebug  : 'env/.stag',
        stagrelease: 'env/.stag',
        proddebug  : 'env/.prod',
        prodrelease: 'env/.prod',
        storybookdebug: 'env/.storybook',
        storybookrelease: 'env/.storybook',
]
apply from: project(':react-native-config').projectDir.getPath() + "/dotenv.gradle"

import com.android.build.OutputFile

/**
 * This is the configuration block to customize your React Native Android app.
 * By default you don't need to apply any configuration, just uncomment the lines you need.
 */
react {
    /* Folders */
    //   The root of your project, i.e. where "package.json" lives. Default is '../..'
    // root = file("../../")
    //   The folder where the react-native NPM package is. Default is ../../node_modules/react-native
    // reactNativeDir = file("../../node_modules/react-native")
    //   The folder where the react-native Codegen package is. Default is ../../node_modules/@react-native/codegen
    // codegenDir = file("../../node_modules/@react-native/codegen")
    //   The cli.js file which is the React Native CLI entrypoint. Default is ../../node_modules/react-native/cli.js
    // cliFile = file("../../node_modules/react-native/cli.js")

    /* Variants */
    //   The list of variants to that are debuggable. For those we're going to
    //   skip the bundling of the JS bundle and the assets. By default is just 'debug'.
    //   If you add flavors like lite, prod, etc. you'll have to list your debuggableVariants.
    // debuggableVariants = ["liteDebug", "prodDebug"]

    /* Bundling */
    //   A list containing the node command and its flags. Default is just 'node'.
    // nodeExecutableAndArgs = ["node"]

    //
    //   The path to the CLI configuration file. Default is empty.
    // bundleConfig = file(../rn-cli.config.js)
    //
    //   The name of the generated asset file containing your JS bundle
    // bundleAssetName = "MyApplication.android.bundle"
    //
    //   The entry file for bundle generation. Default is 'index.android.js' or 'index.js'
    // entryFile = file("../js/MyApplication.android.js")
    //
    //   A list of extra flags to pass to the 'bundle' commands.
    //   See https://github.com/react-native-community/cli/blob/main/docs/commands.md#bundle
    // extraPackagerArgs = []

    /* Hermes Commands */
    //   The hermes compiler command to run. By default it is 'hermesc'
    // hermesCommand = "$rootDir/my-custom-hermesc/bin/hermesc"
    //
    //   The list of flags to pass to the Hermes compiler. By default is "-O", "-output-source-map"
    // hermesFlags = ["-O", "-output-source-map"]

    /* Autolinking */
    autolinkLibrariesWithApp()

    // Added by install-expo-modules
    entryFile = file(["node", "-e", "require('expo/scripts/resolveAppEntry')", rootDir.getAbsoluteFile().getParentFile().getAbsolutePath(), "android", "absolute"].execute(null, rootDir).text.trim())
    cliFile = new File(["node", "--print", "require.resolve('@expo/cli')"].execute(null, rootDir).text.trim())
    bundleCommand = "export:embed"
}

/**
 * Set this to true to create four separate APKs instead of one,
 * one for each native architecture. This is useful if you don't
 * use App Bundles (https://developer.android.com/guide/app-bundle/)
 * and want to have separate APKs to upload to the Play Store.
 */
def enableSeparateBuildPerCPUArchitecture = false

/**
 * Set this to true to Run Proguard on Release builds to minify the Java bytecode.
 */
def enableProguardInReleaseBuilds = false

/**
 * The preferred build flavor of JavaScriptCore (JSC)
 *
 * For example, to use the international variant, you can use:
 * `def jscFlavor = 'org.webkit:android-jsc-intl:+'`
 *
 * The international variant includes ICU i18n library and necessary data
 * allowing to use e.g. `Date.toLocaleString` and `String.localeCompare` that
 * give correct results when using with locales other than en-US. Note that
 * this variant is about 6MiB larger per architecture than default.
 */
def jscFlavor = 'org.webkit:android-jsc:+'

/**
 * Private function to get the list of Native Architectures you want to build.
 * This reads the value from reactNativeArchitectures in your gradle.properties
 * file and works together with the --active-arch-only flag of react-native run-android.
 */
def reactNativeArchitectures() {
    def value = project.getProperties().get("reactNativeArchitectures")
    return value ? value.split(",") : ["armeabi-v7a", "x86", "x86_64", "arm64-v8a"]
}

apply from: "../../node_modules/@sentry/react-native/sentry.gradle"

android {
    ndkVersion rootProject.ext.ndkVersion

    buildToolsVersion rootProject.ext.buildToolsVersion
    compileSdkVersion rootProject.ext.compileSdkVersion

    namespace "com.example"
    flavorDimensions "environment"
    productFlavors {
        dev {
            dimension "environment"
            manifestPlaceholders.networkSecurityConfig = "@xml/network_security_config"
        }

        stag {
            dimension "environment"
            manifestPlaceholders.networkSecurityConfig = "@xml/network_security_config"
        }

        prod {
            dimension "environment"
            manifestPlaceholders.networkSecurityConfig = "@xml/empty_network_security_config"
        }

        storybook {
            dimension "environment"
            manifestPlaceholders.networkSecurityConfig = "@xml/empty_network_security_config"
        }
    }
    defaultConfig {
        multiDexEnabled true
        applicationId project.env.get("ANDROID_APPLICATION_ID")
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion
        versionCode project.hasProperty("versionCode") ? project.properties.get("versionCode").toInteger() : project.env.get("VERSION_CODE").toInteger()
        versionName project.hasProperty("versionNameTime") ? project.env.get("VERSION_NAME") + project.properties.get("versionNameTime") : project.env.get("VERSION_NAME")
        resValue "string", "build_config_package", "com.tisconsumer"
        resValue "string", "app_name", project.env.get("APP_DISPLAY_NAME")
        resValue "string", "com.heapanalytics.android.buildConfigPkgName", "com.tisconsumer"
    }

    splits {
        abi {
            reset()
            enable enableSeparateBuildPerCPUArchitecture
            universalApk false  // If true, also generate a universal APK
            include(*reactNativeArchitectures())
        }
    }
    signingConfigs {
        debug {
            storeFile file('debug.keystore')
            storePassword 'android'
            keyAlias 'androiddebugkey'
            keyPassword 'android'
        }
        release {
            storeFile file("./${project.env.get("ANDROID_KEY_STORE_FILE")}")
            storePassword project.env.get("ANDROID_KEY_STORE_PASSWORD")
            keyAlias project.env.get("ANDROID_KEY_STORE_KEY_ALIAS")
            keyPassword project.env.get("ANDROID_KEY_STORE_KEY_PASSWORD")
        }
    }
    buildTypes {
        debug {
            signingConfig signingConfigs.debug
        }
        release {
            // Caution! In production, you need to generate your own keystore file.
            // see https://reactnative.dev/docs/signed-apk-android.
            signingConfig signingConfigs.release
            minifyEnabled enableProguardInReleaseBuilds
            proguardFiles getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro"
            crunchPngs (findProperty('android.enablePngCrunchInReleaseBuilds')?.toBoolean() ?: true)
        }
    }

    // applicationVariants are e.g. debug, release
    applicationVariants.all { variant ->
        variant.outputs.each { output ->
            // For each separate APK per architecture, set a unique version code as described here:
            // https://developer.android.com/studio/build/configure-apk-splits.html
            // Example: versionCode 1 will generate 1001 for armeabi-v7a, 1002 for x86, etc.
            def versionCodes = ["armeabi-v7a": 1, "x86": 2, "arm64-v8a": 3, "x86_64": 4]
            def abi = output.getFilter(OutputFile.ABI)
            if (abi != null) {  // null for the universal-debug, universal-release variants
                output.versionCodeOverride =
                        defaultConfig.versionCode * 1000 + versionCodes.get(abi)
            }

        }
    }
}

configurations.all {
    resolutionStrategy {
        dependencySubstitution {
            substitute module("org.bouncycastle:bcpkix-jdk18on") using module('org.bouncycastle:bcpkix-jdk15to18:1.69')
            substitute module("org.bouncycastle:bcprov-jdk18on") using module('org.bouncycastle:bcprov-jdk15to18:1.69')
            substitute module("org.bouncycastle:bcprov-ext-jdk18on") using module('org.bouncycastle:bcprov-ext-jdk15to18:1.69')
            substitute module("org.bouncycastle:bcutil-jdk18on") using module('org.bouncycastle:bcutil-jdk15to18:1.69')
        }
    }
}

dependencies {
    // The version of react-native is set by the React Native Gradle Plugin
    implementation("com.facebook.react:react-android")

    implementation("androidx.swiperefreshlayout:swiperefreshlayout:1.0.0")
    implementation("androidx.core:core-splashscreen:1.0.0")

    implementation("androidx.work:work-runtime-ktx:2.8.1")
    implementation("com.onfido.sdk.capture:onfido-capture-sdk:20.2.0") {
        exclude group: "org.bouncycastle"
    }
    implementation("com.onfido.sdk:onfido-workflow:20.2.0") {
        exclude group: "org.bouncycastle"
    }

    if (hermesEnabled.toBoolean()) {
        implementation("com.facebook.react:hermes-android")
    } else {
        implementation jscFlavor
    }
}

task prepare() {
    def flavor = project.env.get("FLAVOR")
    def buildType = gradle.startParameter.taskNames.any { it.toLowerCase().contains("debug") } ? "debug" : "release"
    def envPath = project.ext.envConfigFiles.find({ it.key == "$flavor$buildType" })?.value
    exec {
        workingDir = "$rootProject.projectDir".replace("/android", "")
        args = ['./scripts/prepare.sh', envPath, "android"]
        executable 'sh'
    }
}