State Monad in CoffeeScript

state-monad.coffee

push = (element) -> (stack) ->
  newStack = [element].concat stack
  {value: element, stack: newStack}

pop = (stack) ->
  element = stack[0]
  newStack = stack.slice 1
  {value: element, stack: newStack}

bind = (stackOperation, continuation) -> (stack) ->
  opResult = stackOperation stack
  (continuation opResult.value) opResult.stack

result = (value) -> (stack) ->
  {value: value, stack: stack}

initialStack = []

computation1 = bind \
  (push 4), -> bind \
  (push 5), -> bind \
  pop, (a)  -> bind \
  pop, (b)  ->
    result a + ":" + b

computation2 = bind \
  (push 2), -> bind \
  (push 3), -> bind \
  pop, (a)  -> bind \
  pop, (b)  ->
    result a + ":" + b

composed = bind \
  computation1, (a) -> bind \
  computation2, (b) ->
    result a + ":" + b

finalResult = composed initialStack
console.log finalResult.value

Thanks! I'm glad you found it useful. I created this gist as additional material for a longer article I wrote while I tried myself to understand monads using JavaScript. http://igstan.ro/posts/2011-05-02-understanding-monads-with-javascript.html

have you considered changing the name of the 'result' variable in 'bind'? it's just that because of coffee's weird scope it might be confusing that there two different 'result' var's here. if the definition of 'result' were to come before 'bind' then they would be the same var

also thanks for making this!

@snoble I didn't and for a very simple reason. At the time I wasn't aware of this weird scoping CoffeeScript has. I'll edit the gist. Thanks for your suggestion.

Very Cool!