locations.csv

typesense.fsx

#r "nuget:Typesense"
#r "nuget:FSharp.Data"

open Microsoft.Extensions.DependencyInjection
open Typesense
open Typesense.Setup

let typesense =
    let provider =
        ServiceCollection()
            .AddTypesenseClient(fun config ->
                config.ApiKey <- "typesense"
                config.Nodes <- [ new Node("localhost", "8108", "http") ])
            .BuildServiceProvider()

    provider.GetService<ITypesenseClient>()

let schema =
    Schema(
        "location",
        [
            Field("state", FieldType.String)
            Field("city", FieldType.String)
            Field("location", FieldType.GeoPoint)
        ]
    )

type Location = {
    State: string
    City: string
    Location: float array
}

type GeoLocations = FSharp.Data.CsvProvider<"locations.csv">

let parsed =
    GeoLocations.GetSample().Rows
    |> Seq.map (fun line -> {
        State = line.State
        City = line.City
        Location = [| float line.Latitude; float line.Longitude |]
    })

typesense.DeleteCollection(schema.Name).Result
typesense.CreateCollection(schema).Result
typesense.ImportDocuments(schema.Name, parsed).Result

/// Helper to quickly get an async result within a pipeline. Blocks, don't use in production!
let result (task: System.Threading.Tasks.Task<_>) = task.Result

// basic search
let basicSearchResults =
    typesense.Search<Location>(schema.Name, SearchParameters("MA", "*"))
    |> result
    |> _.Hits
    |> Seq.map (fun (hit: Hit<_>) -> {|
        Score = hit.TextMatchInfo.Score
        Document = hit.Document
    |})
    |> Seq.toArray

// search with geolocation
let locationResults =
    let parameters =
        SearchParameters(
            "*",
            "*",
            FilterBy = "location:(40.7127753, -74.0059728, 50 km)",
            SortBy = "location(40.7127753, -74.0059728):asc"
        )

    typesense.Search("location", parameters)
    |> result
    |> _.Hits
    |> Seq.map (fun (hit: Hit<_>) -> hit.GeoDistanceMeters["location"], hit.Document.City, hit.Document.State)
    |> Seq.toArray