Redirect xref on elisp to the source-directory

elisp-xref-find-def-in-source.el

(defun my/elisp-xref-find-def-in-source (sym)
    "Find elisp files in the source directory."
    (let* ((elisp-xref-find-def-functions nil) ; recurses otherwise
	   (records (elisp--xref-find-definitions sym)))
      (dolist (rec records)
	(when-let* ((file (xref-elisp-location-file (xref-item-location rec)))
		    ( (and (stringp file)
			   (string-match (rx ".el" (? ".gz") eos) file)
			   (file-in-directory-p file lisp-directory)))
		    (relname (file-relative-name file lisp-directory))
		    (src-name (file-name-concat
			       source-directory "lisp"
			       (string-trim-right relname "\\.gz")))
		    ( (file-exists-p src-name)))
	  (setf (xref-elisp-location-file (xref-item-location rec)) src-name)))
      records))
  (add-to-list 'elisp-xref-find-def-functions 'my/elisp-xref-find-def-in-source)

If you compile your own emacs, you might prefer to have xref visit elisp files in the original source directory, not in the install directory. This small function arranges for that to happen by translating file paths for (compressed) elisp files from lisp-directory to source-directory/lisp