GoToMeeting Video Converter/Transcoder

gotomeeting_transcode.bat

@echo off
setlocal EnableDelayedExpansion
REM
REM Transcodes a GoToMeeting video (G2M4 codec, .WMV extension)
REM into a normal .WMV video. Essentially strips the proprietary
REM codec using the provided transcoder.
REM
REM There is a "Convert to Windows Media Player file" setting in
REM GTM that essentially does the same thing as this. However,
REM the transcoding begins IMMEDIATELY after the user terminates
REM the meeting which is problematic if you have back-to-back 
REM meetings to record. You cannot transcode and record at the
REM same time. This file allows users to transcode whenever they
REM want. 
REM 
REM To use, drag a GoToMeeting .WMV video ONTO this file. Change
REM backup_folder_name to whatever name you desire.
REM
REM Based on script found here:
REM http://glenndcitrix.wordpress.com/2012/02/10/3-ways-to-remove-the-gotomeeting-codec-from-your-recording/
REM
REM @author jonswaff
REM @created 2012/10/18
REM

SET max_build=0
SET this_build=0
SET backup_folder_name=GoToMeetingBackup

IF "%ProgramFiles(x86)%XXX"=="XXX" (
  SET "prog_root=%ProgramFiles%"
) ELSE (
  SET "prog_root=%ProgramFiles(x86)%"
)

FOR /F %%X IN ('DIR "%prog_root%\Citrix\GoToMeeting\" /A:D /B') DO (
  SET /A this_build=%%X
  REM ECHO "Checking !this_build! against !max_build!
  IF !this_build! GTR !max_build! (
    SET max_build=!this_build!
  )
)

SET full_path="%prog_root%\Citrix\GoToMeeting\%max_build%\g2mtranscoder.exe"
IF EXIST %full_path% (
  GOTO transcode
) ELSE (
  GOTO notinstalled
)

:transcode
SET current_dir=%~dp0
SET backup_dir=!current_dir!%backup_folder_name%
IF NOT EXIST !backup_dir! MKDIR !backup_dir!
ECHO Backing up source video to !backup_dir!
ECHO.
COPY "%~1" !backup_dir! >nul
ECHO Starting.... Your file will be overwritten with the transcoded version.
ECHO You may verify that the transcoding worked by playing the file with
ECHO VLC Media Player (http://www.videolan.org/vlc/)
%full_path% source=%~1
GOTO:eof

:notinstalled
ECHO I was unable to find the GoToMeeting transcoder file here:
ECHO.
ECHO %full_path%
ECHO.
ECHO Are you sure you have GoToMeeting installed? If it is installed
ECHO in a different location then you need to make changes to this script.
ECHO.
PAUSE
GOTO:eof

You may also refer to this simple guide to convert gotomeeting videos to MP4, AVI, 3GP, MOV, WMV, RMVB etc at http://www.idealshare.net/video-converter/gotomeeting-video-converter.html

GoToMeeting is an online meeting, desktop sharing, and video conferencing software that allow the user to meet with other computer users, customers, clients or colleagues via the Internet in real time. The recording file format of GoToMeeting is WMV with G2M3/G2M4 Codec which is only compatible with GoToMeeting.

To import GoToMeeting files to other software like TechSmith program, you'd better to convert the files to more compatible formats like MP4, AVI, MOV, etc here: http://www.faasoft.com/articles/gotomeeting-video-converter-mac-and-windows.html

After the conversion is done, you can play GoToMeeting files anywhere.