PKGBUILD

# Edited pkgver and md5sum to grab 1.9.1-p376
# for reasons mentioned here: 
# http://www.ruby-lang.org/en/news/2009/12/07/heap-overflow-in-string/
# http://www.ruby-lang.org/en/news/2009/12/07/ruby-1-9-1-p376-is-released/
# -----
# Danny Tatom <dannytatom2gmail.com>

# $Id: PKGBUILD 53111 2009-09-26 06:56:09Z allan $
# Maintainer: Allan McRae <[email protected]>
# Contributor: John Proctor <[email protected]>
# Contributor: Jeramy Rutley <[email protected]>

pkgname=('ruby' 'ruby-docs')
pkgver=1.9.1_p376
_pkgver=1.9.1-p376
pkgrel=2
pkgdesc="An object-oriented language for quick and easy programming"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.ruby-lang.org/en/"
makedepends=('gdbm>=1.8.3' 'db>=4.8' 'openssl>=0.9.8k' 'zlib>=1.2.3.3' \
             'readline>=5.2.013' 'tk>=8.5')
source=(ftp://ftp.ruby-lang.org/pub/ruby/1.9/${pkgname}-${_pkgver}.tar.gz)
options=('!emptydirs')
md5sums=('ebb20550a11e7f1a2fbd6fdec2a3e0a3')

build() {
  cd "${srcdir}/${pkgname}-${_pkgver}"
  ./configure --prefix=/usr --enable-shared --enable-pthread || return 1
  make || return 1
}

package_ruby()
{
  depends=('gdbm>=1.8.3' 'db>=4.8' 'openssl>=0.9.8k' 'zlib>=1.2.3.3' 'readline>=5.2.013')
  provides=('rubygems' 'rake')
  conflicts=('rubygems' 'rake')
  optdepends=('tk: for Ruby/TK')

  cd "${srcdir}/${pkgname}-${_pkgver}"
  make DESTDIR="${pkgdir}" install || return 1
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING" || return 1
}