BubbleSort in brainfuck

bubblesort.bf

BF BubbleSort v0_0
=========================constraints=============================
|arrays of nonzero numbers (could easily fix this by initially  |
|incrementing everything, then decrementing at end, but wont)   |
|five cells at end three containing size less 1                 |
|seven cells workspace at beginning                             |
=================================================================
+>>>>>>>workspace
++++>+++>++>+>+++++>>>++++>++++>+++ create array
<<
[
[ first loop
<<<[<]>>second index
[-<<<<<<+>+>>>>>]<<<<<[->>>>>+<<<<<]>>>> second index to 4
[-<<<<+>+>>>]<<<[->>>+<<<]<< first index to 5
[->-[>]<<]
<[>>[-]>>>>>[>]>>[>]<-<<<<<[<]] decrement no swap counter
<[->>>>>>>[-<+>]>[-<+>]<<[->>+<<]<<<<<<+>>>[-]>>] swap
>>first index
copy first to last plus 2
[-<+<+>>]<[->+<]<[[>]>[>]>+<<[<]<-]>>[-]
shift all
>[[<+>-]>]
copy moved first to last
>[<<+>>-]
>- decrement comparison counter
]
<<<<[<]>
copy first to last plus 2
[-<+<+>>]<[->+<]<[[>]>[>]>+<<[<]<-]>>[-]
shift all
>[[<+>-]>]
copy moved first to last
>[<<+>>-]
>>>[[-]<[-<+<+>>>+<]<<[->>+<<]]>
]