MyCromps-Thead.rakumod

MyCromps-Thead.rakumod

class Cell is export {
	has $.data is required;

	multi method new($data) {
		$.new: :$data
	}

	method RENDER {
		q:to/END/
			<td><.data></td>
		END
	}
}

class Row is export {
	has Cell() @.cells is required;

	multi method new(@cells) {
		$.new: :@cells
	}

	method RENDER {
		q:to/END/
			<tr>
				<@.cells: $c>
					<&Cell($c)>
				</@>
			</tr>
		END
	}
}

class HCell is export {
	has $.data is required;

	multi method new($data) {
		$.new: :$data
	}

	method RENDER {
		q:to/END/
			<th><.data></th>
		END
	}
}

class THead is export {
	has HCell() @.cells is required;

	multi method new(@cells) {
		$.new: :@cells
	}

	method RENDER {
		q:to/END/
			<thead>
				<tr>
					<@.cells: $c>
						<&HCell($c)>
					</@>
				</tr>
			</thead>
		END
	}
}

class MyTable is export {
	has Row() @.rows is required;
	has THead() $.thead;
	
	multi method new(@rows, *%_) {
		$.new: :@rows, |%_
	}

	method RENDER {
		q:to/END/
			<table class="striped">
				<?.thead>
					<&THead(.thead)>
				</?>
				<tbody>
					<@.rows: $r>
						<&Row($r)>
					</@>
				</tbody>
			</table>
		END
	}
}