Dynamic visualisation of point-plane duality in convex geometry

pointPlanesDualityInR2.m

DynamicModule[{pts={{1,1}}, activePoint=None},
	EventHandler[
		Dynamic @ Show[
			Graphics[{
					PointSize@0.04,Dynamic@Point@pts,
					Circle[],
					If[activePoint =!= None,
						{Blue, Point @ pts[[activePoint]]}, {}
					],
					InfiniteLine[# / Norm[#]^2, Cross @ #] & /@ pts // Dynamic
				},
				Axes->True,AxesOrigin->{0,0},Frame->False,PlotRange->ConstantArray[{-2,2},2],
				GridLines->Automatic,AxesStyle->Directive[Large,Black]
			]
		],
		{"MouseClicked":>(AppendTo[pts,MousePosition["Graphics"]]),
		"MouseDown":>If[activePoint === None && Length @ pts > 0,
			{#, Norm[MousePosition["Graphics"] - pts[[#]]]} & /@ Range @ Length @ pts //
			First @* SortBy[Last] // If[
				(* if the closest point is close enough *)
				#[[2]] < 0.1,
				(* then mark which point we are moving *)
				Set[activePoint, #[[1]]]
			]&
		],
		"MouseUp":>If[activePoint =!= None, activePoint = None],
		"MouseDragged":>If[activePoint =!= None,
			Set[pts, ReplacePart[pts, activePoint -> MousePosition["Graphics"]]]
		]}
	]
]