elixir-ah-202206.sparql

PREFIX bk: <http://knetminer.org/data/rdf/terms/biokno/>	PREFIX bkr: <http://knetminer.org/data/rdf/resources/>
PREFIX bka: <http://knetminer.org/data/rdf/terms/biokno/attributes/>	PREFIX bkg: <http://knetminer.org/data/rdf/resources/graphs/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>	PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>	PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>	PREFIX agri: <http://agrischemas.org/>
PREFIX bioschema: <http://bioschemas.org/>	PREFIX schema: <http://schema.org/>

SELECT ?pubTitle ?geneName ?scoreStr ?condLabel ?condTerm
{
  ?pub a agri:ScholarlyPublication;
    dcterms:title ?pubTitle;
    schema:abstract ?pubAbstract;
  .
  
  FILTER ( CONTAINS ( LCASE ( ?pubAbstract ), "yellow rust" ) )
  
  
  ?pub schema:mentions ?gene.

  ?gene a bioschema:Gene;
     schema:name ?geneName;
  .
  
  ?gene bioschema:expressedIn ?condition.

  ?expStatement a rdfs:Statement;
    rdf:subject ?gene;
    rdf:predicate bioschema:expressedIn;
    rdf:object ?condition;
    agri:evidence ?study.

  # Examples of scoring figures
  {
    ?expStatement agri:pvalue ?pvalue; agri:log2FoldChange ?foldChange. 
    FILTER ( ?pvalue < 1e-3 && ABS ( ?foldChange ) > 1.5 )
    BIND ( CONCAT ( "p-value: ", ?pvalue, ", log2 FC: ", ?foldChange ) AS ?scoreStr )
  }
  UNION
  {
    ?expStatement agri:ordinalTpm ?ordinalTpm; agri:tpmCount ?tpm.
    FILTER ( ?ordinalTpm in ('medium', 'high') ) 
    BIND ( CONCAT ( ?tpm, " TPM" ) AS ?scoreStr )
  }

  ?condition schema:name ?condLabel.
  OPTIONAL { ?condition dc:type ?condTerm. }
}
ORDER BY ?geneName