Flatten a list with arbitrary depth in Elixir.

sample.ex

defmodule Sample do
  @moduledoc """
  Sample showcasing the power of Elixir recursion and flattening lists of arbitrary depth.
  """

  @doc """
  Flatten lists with arbitrary depths.

  ## Examples

      iex> Sample.flatten([:foo, [:bar]])
      [:foo, :bar]
  """
  def flatten([]), do: []
  def flatten(list) when not is_list(list), do: [list]
  def flatten([head | rest]), do: flatten(head) ++ flatten(rest)
end

sample_test.ex

defmodule SampleTest do
  use ExUnit.Case
  doctest Sample

  test "should flatten empty list" do
    assert [] = Sample.flatten([])
  end

  test "should flatten list with single element" do
    assert [:foo] = Sample.flatten([:foo])
  end

  test "should flatten list with multiple elements" do
    assert [:foo, :bar] = Sample.flatten([:foo, :bar])
  end

  test "should flatten list with sub list" do
    assert [:foo, :bar] = Sample.flatten([:foo, [:bar]])
  end

  test "should flatten list with crazy depth" do
    assert [:foo, :bar] = Sample.flatten([:foo, [[[[[:bar]]]]]])
  end
end