time_lock_contract.sol

pragma solidity ^0.4.13;

library SafeMath {

  /**
  * @dev Multiplies two numbers, throws on overflow.
  */
  function mul(uint256 a, uint256 b) internal pure returns (uint256) {
    if (a == 0) {
      return 0;
    }
    uint256 c = a * b;
    assert(c / a == b);
    return c;
  }

  /**
  * @dev Integer division of two numbers, truncating the quotient.
  */
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  /**
  * @dev Substracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
  */
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  /**
  * @dev Adds two numbers, throws on overflow.
  */
  function add(uint256 a, uint256 b) internal pure returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }
}

contract Ownable {
  address public owner;


  event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);


  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() public {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) public onlyOwner {
    require(newOwner != address(0));
    OwnershipTransferred(owner, newOwner);
    owner = newOwner;
  }

}

contract ERC20Basic {
  function totalSupply() public view returns (uint256);
  function balanceOf(address who) public view returns (uint256);
  function transfer(address to, uint256 value) public returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

contract BasicToken is ERC20Basic {
  using SafeMath for uint256;

  mapping(address => uint256) balances;

  uint256 totalSupply_;

  /**
  * @dev total number of tokens in existence
  */
  function totalSupply() public view returns (uint256) {
    return totalSupply_;
  }

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[msg.sender]);

    // SafeMath.sub will throw if there is not enough balance.
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of.
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) public view returns (uint256 balance) {
    return balances[_owner];
  }

}

contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) public view returns (uint256);
  function transferFrom(address from, address to, uint256 value) public returns (bool);
  function approve(address spender, uint256 value) public returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) internal allowed;


  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amount of tokens to be transferred
   */
  function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[_from]);
    require(_value <= allowed[_from][msg.sender]);

    balances[_from] = balances[_from].sub(_value);
    balances[_to] = balances[_to].add(_value);
    allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
   *
   * Beware that changing an allowance with this method brings the risk that someone may use both the old
   * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
   * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
   * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) public returns (bool) {
    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifying the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) public view returns (uint256) {
    return allowed[_owner][_spender];
  }

  /**
   * @dev Increase the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To increment
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _addedValue The amount of tokens to increase the allowance by.
   */
  function increaseApproval(address _spender, uint _addedValue) public returns (bool) {
    allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
    Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

  /**
   * @dev Decrease the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To decrement
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _subtractedValue The amount of tokens to decrease the allowance by.
   */
  function decreaseApproval(address _spender, uint _subtractedValue) public returns (bool) {
    uint oldValue = allowed[msg.sender][_spender];
    if (_subtractedValue > oldValue) {
      allowed[msg.sender][_spender] = 0;
    } else {
      allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
    }
    Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

}

contract LoomTimeVault is Ownable {
  // only after the release time the beficiary will be
  // able to transfer the balance of the token
  LoomToken public loomToken;

  // beneficiaries of tokens
  mapping(address => uint256) public beneficiaries; // beneficiary => amount

  // timestamp when token release is enabled
  uint256 public releaseTime;

  // events --------------------------------------------------------------------

  event BeneficiaryAdded(address _beneficiaryAddress, uint256 _amount);
  event BeneficiaryWithdrawn(address _beneficiaryAddress, uint256 _amount);
  event OwnerWithdrawn(address _ownerAddress, uint256 _amount);

  // modifiers -----------------------------------------------------------------

  modifier onlyAfterReleaseTime() {
    require(now >= releaseTime);
    _;
  }

  // constructor function ------------------------------------------------------

  function LoomTimeVault(uint256 _releaseTime, address _loomTokenAddress) public {
    require(_releaseTime > now);
    require(_loomTokenAddress != address(0));

    owner = msg.sender;
    releaseTime = _releaseTime;
    loomToken = LoomToken(_loomTokenAddress);
  }

  // external functions --------------------------------------------------------

  /**
  * @dev the owner of the vault can add the beneficiary accounts
  * @param _beneficiaryAddress address which will receive the benefit in the future
  * @param _amount quantity of tokens to beneficiary receive
  */
  function addBeneficiary(address _beneficiaryAddress, uint256 _amount)
    external
    onlyOwner
  {
    require(_beneficiaryAddress != address(0));
    require(_amount > 0);
    require(_amount <= loomToken.balanceOf(this));

    beneficiaries[_beneficiaryAddress] = _amount;
    BeneficiaryAdded(_beneficiaryAddress, _amount);
  }

  /**
  * @dev the beneficiary can withdraw the tokens from the vault after the time the
  * releaseTime expired, the beneficiary will only receive the amount specified
  */
  function withdraw()
    external
    onlyAfterReleaseTime
  {
    uint256 amount = beneficiaries[msg.sender];
    require(amount > 0);

    beneficiaries[msg.sender] = 0;

    assert(loomToken.transfer(msg.sender, amount));
    BeneficiaryWithdrawn(msg.sender, amount);
  }

  /**
  * @dev the owner of the vault can withdraw the tokens from the vault after the time the
  * releaseTime expire
  */
  function ownerWithdraw()
    external
    onlyOwner
    onlyAfterReleaseTime
  {
    uint256 amount = loomToken.balanceOf(this);
    require(amount > 0);

    assert(loomToken.transfer(msg.sender, amount));
    OwnerWithdrawn(msg.sender, amount);
  }

  /**
  * @dev get how many tokens the beneficiary address has to withdraw after the release time
  * expire
  * @param _beneficiaryAddress address of the beneficiary to inspect
  */
  function beneficiaryAmount(address _beneficiaryAddress)
    public
    view
    returns (uint256)
  {
    return beneficiaries[_beneficiaryAddress];
  }
}

contract LoomToken is StandardToken {
  string public name    = "LoomToken";
  string public symbol  = "LOOM";
  uint8 public decimals = 18;

  // one billion in initial supply
  uint256 public constant INITIAL_SUPPLY = 1000000000;

  function LoomToken() public {
    totalSupply_ = INITIAL_SUPPLY * (10 ** uint256(decimals));
    balances[msg.sender] = totalSupply_;
  }
}