Various Airtable formula snippets

airtable_snipets.sql

-- Get Nth word (replace WORD_N to use)
TRIM(
    MID(
        SUBSTITUTE(
            {Name},
            " ",
            REPT(" ", LEN({Name}))
        ),
        (WORD_N - 1) * LEN({Name}) + 1,
        LEN({Name})
    )
)

-- Reformat phone numbers to ITU format from “Phone number” field
--   First, remove various formatting characters (everything that’s not a number), then:
--   IF the number is a local french one (10 numbers with a leading 0), we add le +33 prefix
--   ELSE IF it’s an international one (00XX, 33XX..), we normalize it to the +XX format
--   ELSE we just keep the cleaned number as-is.
IF(
    LEN(
        TRIM(
            SUBSTITUTE(
            " " & SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
                {Téléphone},
                "/", ""),
                ".", ""),
                ",", ""),
                "-", ""),
                "(", ""),
                ")", ""),
                " ", ""),
                " 0", ""))) = 9,
    "+33" &
        SUBSTITUTE(
        " " & SUBSTITUTE(
        SUBSTITUTE(
        SUBSTITUTE(
        SUBSTITUTE(
        SUBSTITUTE(
        SUBSTITUTE(
        SUBSTITUTE(
            {Téléphone},
            "/", ""),
            ".", ""),
            ",", ""),
            "-", ""),
            "(", ""),
            ")", ""),
            " ", ""),
            " 0", ""),
    TRIM(
        SUBSTITUTE(
        SUBSTITUTE(
        " " & SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
            SUBSTITUTE(
                {Téléphone},
                "/", ""),
                ".", ""),
                ",", ""),
                "-", ""),
                "(", ""),
                ")", ""),
                " ", ""),
        " 00", " +"),
        " 33", " +33")
    )
)

-- Obfuscate french phone numbers
--  The "Phone" column should be the result of the above formula
"+33XXXXXXXX" & RIGHT({Phone}, 4)