Using unconditional-insert! with retract! in a high :salience (initialization) rule

clara-retract-external-fact-example.clj

(require '[clara.rules :as r])
(require '[clara.rules.accumulators :as acc])

(defrecord ExternalFact [id code])
(defrecord DerivedFact [ids])

(r/defrule match-and-remove-it
  {:salience 1000000}
  [?fact <- ExternalFact (= ?id id) (= code "a")]
  =>
  (r/insert-unconditional! (->DerivedFact [?id]))
  (r/retract! ?fact))

(r/defquery find-derived []
  [?facts <- (acc/all) :from [DerivedFact]])

(r/defquery find-external []
  [?facts <- (acc/all) :from [ExternalFact]])

(comment
  (let [facts [(->ExternalFact 1 "a")
               (->ExternalFact 2 "b")
               (->ExternalFact 3 "a")]
        session (-> (r/mk-session [match-and-remove-it find-derived find-external])
                    (r/insert-all facts)
                    r/fire-rules)]
    {:derived (r/query session find-derived)
     :external (r/query session find-external)})
  ;;=
  ;; {:derived ({:?facts [#clara.test_rules.DerivedFact{:ids [1]} #clara.test_rules.DerivedFact{:ids [3]}]}),
  ;;  :external ({:?facts [#clara.test_rules.ExternalFact{:id 2, :code "b"}]})}
  )