screenshot.fish

#!/bin/fish
# vim ft=fish
set -l MONTH (date +"%m")
set -l YEAR (date +"%Y")
set -l SSDIR "$HOME/Pictures/Screenshots/$YEAR-$MONTH"
mkdir -p $SSDIR

if test "$argv[1]" = "display"
    if maim /tmp/screenshot.png
        xclip -selection clipboard -t image/png -i /tmp/screenshot.png
        set -l SSPATH $SSDIR/(date +%s)-(identify -format '%wx%h' /tmp/screenshot.png).png
        mv /tmp/screenshot.png $SSPATH
    end
end

# https://stefanscherer.github.io/how-to-take-screenshots-with-drop-shadow/
function add_shadow -a image
    convert $image \( +clone -background grey35 -shadow 80x8+5+5 \) \
        +swap -background transparent -layers merge +repage $image
end

if test "$argv[1]" = "window"
    if maim -i (xdotool getactivewindow) /tmp/screenshot.png
        xclip -selection clipboard -t image/png -i /tmp/screenshot.png
        set -l SSPATH $SSDIR/(date +%s)-(identify -format '%wx%h' /tmp/screenshot.png).png
        mv /tmp/screenshot.png $SSPATH
        add_shadow $SSPATH
    end
end

if test "$argv[1]" = "area" 
    maim /tmp/screenshotbg.png 
    sxiv -fbZ /tmp/screenshotbg.png & 
    sleep 0.5 #ensure sxiv won't override slop
    if maim -s -b 1920 -r blur1,blur2 /tmp/screenshot.png
        xclip -selection clipboard -t image/png -i /tmp/screenshot.png
        set -l SSPATH $SSDIR/(date +%s)-(identify -format '%wx%h' /tmp/screenshot.png).png
        mv /tmp/screenshot.png $SSPATH
        add_shadow $SSPATH
    end
    #time to kill
    xdotool key q
end