Advent of Code 2015; Day 1.

day-1.lisp

(defparameter *instruction->move*
              '((#\( . 1+)
                (#\) . 1-))
  "Map instructions to floor movements.")

(defun all-floors (instructions)
  "Return a sequence of all floors passed through when starting at floor 0 and
   following the list of INSTRUCTIONS."
  (reverse (reduce #'(lambda (acc i)
                       (cons (funcall (cdr (assoc i *instruction->move*))
                                      (car acc))
                             acc))
                   instructions
                   :initial-value '(0))))

(defun where-is-santa (file)
  "If Santa starts at floor 0 and follows the instructions in FILE, at which
   floor does he finish?"
  (car (last (all-floors (uiop:read-file-line file)))))

(defun first-basement-instruction (file)
  "If Santa starts at floor 0 and follows the instructions in FILE, what is
   the ordinal number of the instruction that he has just followed when he
   first enters a basement floor (floor < 0)?"
  (position -1 (all-floors (uiop:read-file-line file))))