Drip tray for Eurkea Mignon grinders

Eurkea_Mignon_drip_tray.scad

// Thickness of the bottom of the tray itself.
base_z = 0.5;

// The width of the rim around the tray.
rim_width = 2;

// Height of the rim around the tray. This is the height over base_z.
rim_z = 2;

// Length of the drip tray (not including the notch).
drip_y = 80;

// Radius for the edges. 0 would result in chamfer edges.
edge_r = 2;

module 2d_base() {
  // machine measurments from https://grabcad.com/library/eureka-mignon-espresso-grinder-1  
  MACHINE_X = 120;
  NOTCH_X = 68;
  NOTCH_Y = 18;
  
  // base is symmetrical, with notch
  // exactly in the middle
  notch_start_x = (MACHINE_X - NOTCH_X) / 2;
  
  offset(r = edge_r) 
    offset(delta = -edge_r) 
      polygon([
        [0, 0], 
        [0, drip_y],
        [notch_start_x, drip_y],
        [notch_start_x, drip_y + NOTCH_Y],
        [notch_start_x + NOTCH_X, drip_y + NOTCH_Y],
        [notch_start_x + NOTCH_X, drip_y],
        [MACHINE_X, drip_y],
        [MACHINE_X, 0]]);
}

union() {
  linear_extrude(base_z) 2d_base();  
  linear_extrude(base_z + rim_z) difference() {
    2d_base();
    offset (delta=-rim_width) 2d_base();
  }
}