gtklp with patches from debian

PKGBUILD

# Maintainer:  Dimitris Kiziridis <ragouel at outlook dot com>
# Contributor: Steven Allen <[email protected]>
# Contributor: Tobias Mueller <[email protected]>

pkgname=gtklp
pkgver=1.3.4
pkgrel=2
pkgdesc="A graphical frontend for cups, the linux printing system"
arch=('i686' 'x86_64')
url="http://gtklp.sirtobi.com"
license=('GPL')
depends=('cups' 'gtk2')
makedepends=('gcc' 'base-devel' "patch")
source=("${pkgname}-${pkgver}.src.tar.gz::https://sourceforge.net/projects/gtklp/files/gtklp/${pkgver}/gtklp-${pkgver}.src.tar.gz/download"
  "http://deb.debian.org/debian/pool/main/g/gtklp/gtklp_1.3.4-3.debian.tar.xz"
)
sha256sums=('be07609042595fa932034e3b2d7038cef33901ec0863fcedbb5188acb6b53bab'
  '4097010d87b0987f8bc8d7a2be0bff1f70f47ed6753d5402e35562025de2c32a')

prepare() {
  cd "${pkgname}-${pkgver}"
  for f in ../debian/patches/{*.patch,bugs/*.diff,debian/*.diff}; do
    patch -Np1 <$f
  done

}
build() {
  cd "${pkgname}-${pkgver}"
  aclocal -I m4
  autoheader --force
  autoconf --force
  automake --add-missing --copy --include-deps --foreign --force-missing
  ./configure --prefix=/usr
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}