Revised PKGBUILD for urlview

PKGBUILD

# Maintainer: Jaroslav Lichtblau <[email protected]>

pkgname=urlview
pkgver=0.9
pkgrel=7
_patchlevel=18.1
pkgdesc="A curses URL parser for text files"
arch=('i686' 'x86_64')
url="http://packages.qa.debian.org/u/urlview.html"
license=('GPL')
depends=('bash' 'ncurses')
source=(http://ftp.debian.org/debian/pool/main/u/urlview/${pkgname}_$pkgver.orig.tar.gz \
        http://ftp.debian.org/debian/pool/main/u/urlview/${pkgname}_$pkgver-$_patchlevel.diff.gz)
md5sums=('4f253c82b59136181b1f0bf218ef059d'
         '086e93a4a93dd989751e471f3f2d1e47')

prepare() {
  cd ${srcdir}/$pkgname-$pkgver.orig
  patch -Np1 -i ${srcdir}/${pkgname}_${pkgver}-$_patchlevel.diff
}

build() {
  cd ${srcdir}/$pkgname-$pkgver.orig
  ./configure --prefix=/usr
  make
}

package() {
  cd ${srcdir}/$pkgname-$pkgver.orig

  install -d ${pkgdir}/etc/urlview ${pkgdir}/usr/share/man/man1
  make prefix=${pkgdir}/usr mandir=${pkgdir}/usr/share/man install

  install -D -m755 url_handler.sh ${pkgdir}/etc/urlview/url_handler.sh
  install -D -m644 sample.urlview ${pkgdir}/etc/urlview/system.urlview
  install -d ${pkgdir}/usr/bin
  ln -fs /etc/urlview/url_handler.sh ${pkgdir}/usr/bin/url_handler.sh
}