apache-qpid-* (version 0.22) PKGBUILD scripts for AUR

apache-qpid-cpp-0.22_PKGBUILD

# Maintainer: Ciriaco Garcia de Celis <cgarcia at etherpilot.com>
pkgname=apache-qpid-cpp
pkgver=0.22
pkgrel=1
pkgdesc="apache qpid C++ broker and client"
arch=('i686' 'x86_64')
url="http://qpid.apache.org/index.html"
license=('APACHE')
makedepends=('util-linux' 'boost' 'python2')
depends=('boost>=1.50')
optdepends=()
source=("http://www.eu.apache.org/dist/qpid/$pkgver/qpid-cpp-$pkgver.tar.gz" "patch-boost-1.50")
md5sums=('65704b9652427ac711cb64e358b52d11' '5d049061409823c2ddcece73bba18b62')

build() {
  cd "$srcdir/qpidc-$pkgver"
  sed -i '1 s/python$/python2/' \
    src/tests/interlink_tests.py \
    src/tests/ha_store_tests.py \
    src/tests/ha_tests.py \
    src/tests/qpid-ctrl \
    src/tests/header_test.py \
    src/tests/brokertest.py \
    src/tests/qpid-cpp-benchmark \
    bindings/qmf/tests/python_console.py \
    bindings/qmf/tests/python_agent.py \
    managementgen/qmf-gen

  # cd "$srcdir/qpidc-$pkgver" && patch -p1 < ../../patch-boost-1.50

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var
  make all
}

package() {
  cd "$srcdir/qpidc-$pkgver"

  make DESTDIR="$pkgdir/" install
}

# vim:set ts=2 sw=2 et:

apache-qpid-python-0.22_PKGBUILD

# Maintainer: Ciriaco Garcia de Celis <cgarcia at etherpilot.com>
pkgname=apache-qpid-python
pkgver=0.22
pkgrel=1
pkgdesc="Python client connector for the apache qpid server"
arch=('any')
url="http://qpid.apache.org"
license=('APACHE')
depends=('python2')
makedepends=('python2')
optdepends=()
source=(http://www.eu.apache.org/dist/qpid/$pkgver/qpid-python-$pkgver.tar.gz)
md5sums=('e7d088a4cf55fe3dc246bd613bcf4460')

package() {
  cd "$srcdir/qpid-$pkgver/python"

  python2 setup.py install --root=${pkgdir}/ --optimize=1

  for tool in drain server spout
  do
    install -p examples/api/${tool} "${pkgdir}/usr/bin/qpid-${tool}"
    sed -i '1 s/python$/python2/' "${pkgdir}/usr/bin/qpid-${tool}"
  done
}

# vim:set ts=2 sw=2 et:

apache-qpid-qmf-0.22_PKGBUILD

# Maintainer: Ciriaco Garcia de Celis <cgarcia at etherpilot.com>
pkgname=apache-qpid-qmf
pkgver=0.22
pkgrel=1
pkgdesc="apache qpid management framework API"
arch=('any')
url="http://qpid.apache.org"
license=('APACHE')
depends=('python2')
makedepends=('python2')
optdepends=()
source=(http://www.eu.apache.org/dist/qpid/$pkgver/qpid-qmf-$pkgver.tar.gz)
md5sums=('c690732dd4345c604ff6bd1c0c13b71a')

package() {
  cd "$srcdir/qpid-qmf-$pkgver"

  python2 setup.py install --root=${pkgdir}/ --optimize=1
}

# vim:set ts=2 sw=2 et:

apache-qpid-tools-0.22_PKGBUILD

# Maintainer: Ciriaco Garcia de Celis <cgarcia at etherpilot.com>
pkgname=apache-qpid-tools
pkgver=0.22
pkgrel=1
pkgdesc="apache qpid command-line tools"
arch=('any')
url="http://qpid.apache.org"
license=('APACHE')
depends=('python2' 'apache-qpid-python' 'apache-qpid-qmf')
makedepends=('python2')
optdepends=()
source=(http://www.eu.apache.org/dist/qpid/$pkgver/qpid-tools-$pkgver.tar.gz)
md5sums=('59e3731d6687655c6f3495597da6284d')

package() {
  cd "$srcdir/qpid-tools-$pkgver"

  python2 setup.py install --root=${pkgdir}/ --optimize=1
}

# vim:set ts=2 sw=2 et: