Simple groovy script to show changes in Arch Linux kernel config

arch-config-diff.groovy

#!/usr/bin/env groovy

if (!args) {
    throw new IllegalArgumentException('Expected commit as only arg')
}

def commit = args[0]
println "Getting changes for commit: $commit"
def url = "https://git.archlinux.org/svntogit/packages.git/patch/trunk/config?id=$commit".toURL()

def adds = [] as Set
def removes = [] as Set

url.eachLine {
    if (it.contains('CONFIG')) {
        def first = it[0]
        def line = it.drop(1)
        if (line[0..1] == '# ') {
            line = line.drop(2)
        }

        if (first == '+') {
            adds << line
        } else if (first == '-') {
            removes << line
        }
    }
}
println("Adds: ${adds.size()} Removes: ${removes.size()}")

def realAdds = adds - removes
def realRemoves = removes - adds
println("Real Adds: ${realAdds.size()} Real Removes: ${realRemoves.size()}")

def all = []
all += realAdds.collect { "+$it" }
all += realRemoves.collect { "-$it" }

all.sort { it.drop(1) }.each { println it }