CreatePackage.bat

@echo off
set PROJECT_NAME=SampleGame
set PROJECT_ROOT_PATH=%CD%\..
set PROJECT_PATH=%PROJECT_ROOT_PATH%\%PROJECT_NAME%\%PROJECT_NAME%.uproject
set ENGINE_PATH="C:\Program Files\UnrealEngine\UE_5.3\Engine\Binaries\Win64\UnrealEditor.exe"
set BUILD_BATCH_PATH="C:\Program Files\UnrealEngine\UE_5.3\Engine\Build\BatchFiles\RunUAT.bat"

:LABEL_SELECT_BUILD_CONFIGULATION
echo Select BuildType. (Debug / Development / Shipping)
set /p SELECT_BUILD_TYPE=" >>> "
if %SELECT_BUILD_TYPE%==Debug (
    goto LABEL_SET_VARIABLE
) else if %SELECT_BUILD_TYPE%==Development (
    goto LABEL_SET_VARIABLE
) else if %SELECT_BUILD_TYPE%==Shipping (
    goto LABEL_SET_VARIABLE
) else (
    echo Wrong input. Please input again.
    goto LABEL_SELECT_BUILD_CONFIGULATION
)

:LABEL_SET_VARIABLE
set PLATFORM_TYPE=Win64
set NOWDATE=%date:/=%
set TMPTIME=%time: =0%
set NOWTIME=%TMPTIME:~0,2%%TMPTIME:~3,2%%TMPTIME:~6,2%
set ARCHIVE_DIRECTORY_NAME=%PROJECT_NAME%_%SELECT_BUILD_TYPE%_%NOWDATE%_%NOWTIME%
set PACKAGE_PATH=%PROJECT_ROOT_PATH%\Rom\%PLATFORM_TYPE%\%SELECT_BUILD_TYPE%\Raw\%ARCHIVE_DIRECTORY_NAME%
set ZIP_FILE_PATH=%PROJECT_ROOT_PATH%\Rom\%PLATFORM_TYPE%\%SELECT_BUILD_TYPE%\Zip\%ARCHIVE_DIRECTORY_NAME%

:LABEL_BUILD_ROM
echo Start to package project.
call %BUILD_BATCH_PATH% BuildCookRun -project="%PROJECT_PATH%" -platform=%PLATFORM_TYPE% -clientconfig=%SELECT_BUILD_TYPE% -noP4 -clean -build -cook -stage -pak -archive -archivedirectory="%PACKAGE_PATH%"
echo End to package project.

:LABEL_SELECT_ZIP_NEED
echo Do you want to create a zipped package? (y / n)
set /p NEED_ZIP_FILE=" >>> "
if %NEED_ZIP_FILE%==y (
    goto LABEL_CREATE_ZIP_FILE
) else if %NEED_ZIP_FILE%==n (
    goto END
) else (
    echo Wrong input. Please input again.
    goto LABEL_SELECT_ZIP_NEED
)

:LABEL_CREATE_ZIP_FILE
echo Start to create a zip file.
call %BUILD_BATCH_PATH% ZipUtils -add=%PACKAGE_PATH% -archive=%ZIP_FILE_PATH%.zip
echo End to create a zip file.

:END
pause